Mercurial > hg > ucx / file revision

#
# DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS HEADER.
#
# Copyright 2021 Mike Becker, Olaf Wintermann All rights reserved.
#
# Redistribution and use in source and binary forms, with or without
# modification, are permitted provided that the following conditions are met:
#
#   1. Redistributions of source code must retain the above copyright
#      notice, this list of conditions and the following disclaimer.
#
#   2. Redistributions in binary form must reproduce the above copyright
#      notice, this list of conditions and the following disclaimer in the
#      documentation and/or other materials provided with the distribution.
#
# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
# AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
# IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
# ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE
# LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
# CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
# SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
# INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
# CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
# ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
# POSSIBILITY OF SUCH DAMAGE.
#

set(PANDOC_DESTDIR ${CMAKE_BINARY_DIR}/docs/web)
set(PANDOC_ARGS -c ucx.css -B header.html -A footer.html -T 'UAP Common Extensions')
set(PANDOC_SRC index.md license.md install.md features.md)
set(LOGO_PATH ../../uaplogo.png)

if (NOT EXISTS ${PANDOC_EXECUTABLE})
    find_program(PANDOC_EXECUTABLE pandoc)
    if(NOT EXISTS ${PANDOC_EXECUTABLE})
        message(WARNING "Pandoc not found, docs-html target will not be generated.")
        return()
    endif()
endif()

message(STATUS "HTML Documentation will be generated at: ${PANDOC_DESTDIR}.")
file(MAKE_DIRECTORY ${PANDOC_DESTDIR})

# UCX 3.0 documentation
foreach(source_file ${PANDOC_SRC})
    string(REPLACE .md .html dest_file ${source_file})
    string(PREPEND dest_file "${PANDOC_DESTDIR}/")
    list(APPEND PANDOC_DEST ${dest_file})
    add_custom_command(
            OUTPUT ${dest_file}
            COMMAND ${PANDOC_EXECUTABLE} ${PANDOC_ARGS}  -o ${dest_file} ${source_file}
            WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
            MAIN_DEPENDENCY ${source_file}
            DEPENDS header.html footer.html
    )
endforeach()

# UCX 2.1 documentation
add_custom_target(docs-html-21
        COMMAND ${PANDOC_EXECUTABLE} -c ucx.css -B header-ucx2.html -A footer.html
            -T 'UAP Common Extensions' -o ${PANDOC_DESTDIR}/modules-ucx2.html modules-ucx2.md
        WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
        DEPENDS modules-ucx2.md header-ucx2.html footer.html
        COMMENT "Adding UCX 2.1 HTML documentation."
)

# Collect all HTML documentation
add_custom_target(docs-html
        COMMAND ${CMAKE_COMMAND} -E copy ucx.css ${PANDOC_DESTDIR}/ucx.css
        COMMAND ${CMAKE_COMMAND} -E copy ${LOGO_PATH} ${PANDOC_DESTDIR}/uaplogo.png
        DEPENDS ${PANDOC_DEST} docs-html-21
        WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
        COMMENT "Generating HTML documentation with pandoc."
)