CMakeLists.txt

cmake_minimum_required(VERSION 3.14)
project(ucx VERSION 3.0 DESCRIPTION "UAP Common Extensions")

# Configuration
set(CMAKE_C_STANDARD 11)
set(CMAKE_C_STANDARD_REQUIRED  99)

# Library
add_subdirectory(src)

# Tests
enable_testing()
add_subdirectory(test)

# Web Documentation
add_subdirectory(docs/src)

# API Documentation
find_package(Doxygen)
option(BUILD_DOCUMENTATION "Create API documentation." ${DOXYGEN_FOUND})

if(BUILD_DOCUMENTATION)
    if(NOT DOXYGEN_FOUND)
        message(FATAL_ERROR "Doxygen is needed to build the documentation.")
    endif()

    set(DOXY_INPUT ${CMAKE_SOURCE_DIR}/src)
    set(DOXY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/docs)
    set(DOXY_PROJECT_LOGO ${CMAKE_SOURCE_DIR}/uaplogo.png)

    configure_file(${CMAKE_SOURCE_DIR}/cmake_infile.doxygen ${CMAKE_BINARY_DIR}/Doxyfile)

    add_custom_target(docs-api-21
            COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_SOURCE_DIR}/docs/api-2.1 ${CMAKE_BINARY_DIR}/docs/web/api-2.1
            WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
            COMMENT "Copying UCX 2.1 API documentation.")

    add_custom_target(docs-api
            COMMAND ${DOXYGEN_EXECUTABLE}
            WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
            COMMENT "Generating API documentation with Doxygen.")

    add_custom_target(docs-all DEPENDS docs-html docs-api docs-api-21)
else()
    add_custom_target(docs-all DEPENDS docs-html)
endif()